ACCESSの印刷設定で用紙サイズや給紙方法が用意されていない場合、簡単に設定できない・・・。
用紙サイズや給紙方法は割り当てられている数字をセットすれば良いみたいで、WindowsAPIを使って取得できるようなので、色々参考にして↓の関数を作成。
共通モジュールに取得関数を作成。
--------------------------------------------------------------------
Private Declare Function OpenPrinter Lib "winspool.drv" Alias "OpenPrinterA" (ByVal pPrinterName As String, phPrinter As Long, ByVal pDefault As Long) As Long
Private Declare Function ClosePrinter Lib "winspool.drv" (ByVal hPrinter As Long) As Long
' プリンタデバイスドライバの能力を取得する関数の宣言
Private Declare Function DeviceCapabilities Lib "winspool.drv" Alias "DeviceCapabilitiesA" (ByVal pDevice As String, ByVal pPort As String, ByVal fwCapability As Long, pOutput As Any, pDevMode As Any) As Long
' ある位置から別の位置にメモリブロックを移動する関数の宣言
Private Declare Sub MoveMemory Lib "kernel32.dll" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
'PC名を取得する関数の宣言
Private Declare Function GetComputerName Lib "kernel32.dll" Alias "GetComputerNameA" (ByVal lpBuffer As String, nSize As Long) As Long
Private Const DC_PAPERNAMES = 16
Private Const DC_PAPERS = 2
Private Const DC_BINNAMES = 12
Private Const DC_BINS = 6
'==================================================
'用紙サイズの番号を取得
'
'paraPrinterName：プリンタ名
'paraPaperName：用紙名
'==================================================
Public Function GetPaperSizeNumber(paraPrinterName As String, paraPaperName As String) As Integer
Dim lPaperCount As Long
Dim lCounter As Long
Dim hPrinter As Long
Dim sDevicePort As String
Dim bytPaper() As Byte
Dim strPaperName As String * 64
Dim aintNubytPaper() As Integer
Dim onePaperName As String
GetPaperSizeNumber = -1
sDevicePort = ""
If OpenPrinter(paraPrinterName, hPrinter, 0) <> 0 Then
' バッファに必要なサイズ(用紙数)を取得
lPaperCount = DeviceCapabilities(paraPrinterName, sDevicePort, DC_PAPERNAMES, ByVal vbNullString, 0)
ReDim bytPaper(64 - 1, lPaperCount - 1)
ReDim aintNubytPaper(1 To lPaperCount)
'用紙名を取得
Call DeviceCapabilities(paraPrinterName, sDevicePort, DC_PAPERNAMES, bytPaper(0, 0), 0)
'用紙番号を取得
Call DeviceCapabilities(paraPrinterName, sDevicePort, DC_PAPERS, aintNubytPaper(1), ByVal vbNullString)
For lCounter = 0 To lPaperCount - 1
' 用紙名コピー
MoveMemory ByVal strPaperName, bytPaper(0, lCounter), 64
' 用紙名追加
onePaperName = Left(strPaperName, InStr(strPaperName, vbNullChar) - 1)
' 指定の用紙名が入っていたらその用紙番号を返す
If InStr(LCase(onePaperName), LCase(paraPaperName)) > 0 Then
GetPaperSizeNumber = aintNubytPaper(lCounter + 1)
Exit For
End If
Next lCounter
ClosePrinter (hPrinter)
End If
End Function
'==================================================
'給紙方法の番号を取得
'
'paraPrinterName：プリンタ名
'paraPaperName：給紙方法
'==================================================
Public Function GetBinNumber(paraPrinterName As String, paraBinName As String) As Integer
Dim lBinCount As Long
Dim lCounter As Long
Dim hPrinter As Long
Dim sDevicePort As String
Dim bytBin() As Byte
Dim strBinName As String * 24
Dim aintNubytBin() As Integer
Dim oneBinName As String
GetBinNumber = -1
sDevicePort = ""
If OpenPrinter(paraPrinterName, hPrinter, 0) <> 0 Then
' バッファに必要なサイズ(給紙方法数)を取得
lBinCount = DeviceCapabilities(paraPrinterName, sDevicePort, DC_BINNAMES, ByVal vbNullString, 0)
ReDim bytBin(24 - 1, lBinCount - 1)
ReDim aintNubytBin(1 To lBinCount)
'給紙方法名を取得
Call DeviceCapabilities(paraPrinterName, sDevicePort, DC_BINNAMES, bytBin(0, 0), 0)
'給紙方法番号を取得
Call DeviceCapabilities(paraPrinterName, sDevicePort, DC_BINS, aintNubytBin(1), ByVal vbNullString)
For lCounter = 0 To lBinCount - 1
' 給紙方法名コピー
MoveMemory ByVal strBinName, bytBin(0, lCounter), 24
' 給紙方法名追加
oneBinName = Left(strBinName, InStr(strBinName, vbNullChar) - 1)
' 指定の給紙方法名が入っていたらその給紙方法番号を返す
If InStr(LCase(oneBinName), LCase(paraBinName)) > 0 Then
GetBinNumber = aintNubytBin(lCounter + 1)
Exit For
End If
Next lCounter
ClosePrinter (hPrinter)
End If
End Function
--------------------------------------------------------------------
これを使用してレポート設定時に↓のように文字列で用紙サイズや給紙方法が設定出来る！
--------------------------------------------------------------------
'用紙サイズ
rpt.Printer.PaperSize = GetPaperSizeNumber(prtName, "用紙名")
'給紙用法
rpt.Printer.PaperBin = GetBinNumber(prtName, "給紙方法名")
--------------------------------------------------------------------
